微信 聊天记录保存位置

微信4.0.xx版本用户数据存储位置指定方法:操作如下：

1. 关闭微信4.0
2. 移动C:\Users\***\Documents\xwechat_files到目标目录，如 F:\Documents\xwechat_files
3. 修改C:\Users\***\AppData\Roaming\Tencent\xwechat\config\***.ini（例如：51a1fffea11325a1e4104c6b3de47af7.ini）中的文件存储路径，之后启动微信4.0

默认值为

MyDocument:

修改为

F:\Documents​

微信3.9.xx版本用户数据存储位置指定方法:

%appdata%\Tencent\WeChat\All Users\config 下面有一个3ebffe94.ini，用记事本打开就是当前计算机用户下微信的默认数据存放目录：

微信多开程序

微信3.9版本：Weixindk微信3.9版本多开先运行一下即可多开一个.rar

微信4.x版本：Weixindk(微信4.x版本多开).rar

微信4.x版本，使用多配置目录实现电脑自动登录微信功能脚本：

微信多配置目录自动登录方法.rar

脚本示例:

@echo off
setlocal
REM 方法一：global_config 文件是常驻内存的，无法直接替换，而且自动登录配置文件有有效期，过一段时间会失效。
REM copy "%~dp0autologin\yhyg\xwechat_files_all_users_config" "%~dp0all_users\config" /y
REM copy "%~dp0autologin\yhyg\appdata_xwechat_net_host" "%appdata%\Tencent\xwechat\net\host" /y
REM 方法二：在微信启动前配置文件，更改微信数据目录文件，启动完成后更改为总配置文件目录。

REM 更改微信配置文件路径%appdata%\Tencent\xwechat\config\51a1fffea11325a1e4104c6b3de47af7.ini：
set target="%appdata%\Tencent\xwechat\config\51a1fffea11325a1e4104c6b3de47af7.ini"
REM 配置目录新路径，要更改路径只需改这个即可，不是盘符根目录时，不需要后面的\
set targetpath=D:\Wechat_YG

REM 判断此配置目录是否已经被打开，如果打开就跳过并提示已经打开，并延时3秒关闭
set "dirpath=%targetpath%\xwechat_files\all_users"
REM 提取父目录和目录名
for %%I in ("%dirpath%") do (
    set "parent=%%~dpI"
    set "dirname=%%~nxI"
)
REM 尝试重命名目录
ren "%dirpath%" "%dirname%.tmp"
set "err=%errorlevel%"
if %err% neq 0 (
    echo 目录 %dirpath% 被占用
    echo 此配置目录下的微信已经启动，请勿重复启动（重复启动将删除自动登录信息）
    goto :Exit
) else (
    echo 目录 %dirpath% 没被占用
    rem 改回原目录名
    ren "%parent%%dirname%.tmp" "%dirname%"
)
REM 读取原始内容到变量
set "orig_content="
if exist %target% set /p orig_content=<%target%

REM 写入新的路径
ECHO 写入新的配置目录路径成功
<nul set /p =%targetpath%> %target%

ping 127.0.0.1 -n 3 > nul
REM 检查是否有 Weixin.exe 进程
tasklist /FI "IMAGENAME eq Weixin.exe" | find /I "Weixin.exe" >nul

IF ERRORLEVEL 1 (
    REM 没有微信进程，启动官方微信
    start "" "C:\Program Files\Tencent\Weixin\Weixin.exe"
) ELSE (
    REM 有微信进程，启动多开
    start "" "%~dp0autologin\微信多开.exe"
)

REM 等待2秒，微信启动成功后还原本来的路径
ping 127.0.0.1 -n 2 > nul
REM 恢复原内容
if defined orig_content (
    <nul set /p =%orig_content%> %target%
    echo 配置目录文件已恢复原始内容
) else (
    echo 文件原本为空，无需恢复
)
ECHO 洋行科技已经启动微信成功，可以看到微信登录界面了。
:Exit
ping 127.0.0.1 -n 3 > nul